AskSensors IoT Platform Documentation


Connect Hardware to AskSensors over MQTT


AskSensors MQTT Summary:

1-MQTT Publish/Subscribe API

2-Connect ESP8266 over MQTT

3-Connect ESP32 over MQTT

4-Connect Arduino Ethernet over MQTT



3-Connect ESP32 over MQTT

This guide explains how to use your ESP32 to publish data to the AskSensors IoT platform over MQTT.


a) Prerequisites :

b) Hardwares Requirements:
  • Computer running Arduino software (version 1.8.7 or higher).
  • ESP32 board.
  • USB micro cable to connect the ESP32 board to the computer.

c) Install ESP32 in Arduino IDE:
    Follow the instructions below to install the ESP32 board in your Arduino IDE:
  • Install the latest version of Arduino IDE software (1.8.7 or higher).
  • Open the preferences window from the Arduino IDE : File> Preferences.
  • Go to the "Additional Board Manager URLs" field, Enter the following URL:
    https://dl.espressif.com/dl/package_esp32_index.json
    If you already have the ESP8266 boards URL, separate the URLs with a comma as show below:
    https://dl.espressif.com/dl/package_esp32_index.json, http://arduino.esp8266.com/stable/package_esp8266com_index.json
    Now, open boards manager (Tools > Board > Boards Manager), search for ESP32 and click the install button for the "ESP32 by Espressif Systems".

d) Software :
The provided code includes the libraries for both connecting to a WiFi network and to publish data to AskSensors using MQTT.
You need to fill the following:

  • Your WIFI SSID and password.
  • The Api Key In and username to set the MQTT Topic:username/apiKeyIn
  •   const char* ssid = "....."; // Wifi SSID
      const char* password = ".....";// Wifi Password
      const char* username = "................."; // my AskSensors username
      const char* pubTopic = "......./....."; // username/apiKeyIn
      const char* mqtt_server = "mqtt.asksensors.com";

e) Run the code
    Now it's time to connect your board.
  • Connect your ESP32 board to the computer via serial/USB and upload the code using the Arduino IDE.
  • Return back to your sensor page on AskSensors, Click on'Show Graph' and select the chart type (such as Line, Bar, Binary..) to visualize your sensor data stream in graph.
  • Open a serial terminal. You can cross-check the AskSensors graph readings with the values being printed on your Arduino Terminal.

f) Source Code :
A basic source code is shown below. Please refer to the AskSensors Github page to get the latest version and updates.
/*
* MQTT and AskSensors IoT Platform
* Description: ESP32 sends data to AskSensors using MQTT
* Author: https://asksensors.com, 2019
* github: https://github.com/asksensors/AskSensors-ESP32-MQTT
*/
#include <WiFi.h>
#include <PubSubClient.h>
// TODO: AskSensors MQTT user config
const char* ssid = ".................."; // Wifi SSID
const char* password = ".................."; // Wifi Password
const char* username = "................."; // my AskSensors username
const char* pubTopic = "................/.................."; // username/apiKeyIn
const unsigned int writeInterval = 25000; // write interval (in ms)
// MQTT host config
const char* mqtt_server = "mqtt.asksensors.com";
unsigned int mqtt_port = 1883;
WiFiClient askClient;
PubSubClient client(askClient);
void setup() {
  Serial.begin(115200);
  Serial.println("*****************************************************");
  Serial.println("********** Program Start : ESP32 publishes data to AskSensors over MQTT");
  Serial.print("********** connecting to WIFI : ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("->WiFi connected");
  Serial.println("->IP address: ");
  Serial.println(WiFi.localIP());
  client.setServer(mqtt_server, mqtt_port);
  client.setCallback(callback);
}
void loop() {
  if (!client.connected())
    reconnect();
  client.loop();
  Serial.println("********** Publish MQTT data to ASKSENSORS");
  char mqtt_payload[30] = "";
  snprintf (mqtt_payload, 100, "m1=%ld&m2=%ld", random(10,100), random(10,100) );
  Serial.print("Publish message: ");
  Serial.println(mqtt_payload);
  client.publish(pubTopic, mqtt_payload);
  Serial.println("> MQTT data published");
  Serial.println("********** End ");
  Serial.println("*****************************************************");
  delay(writeInterval);// delay
}
void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }
  Serial.println();
}
void reconnect() {
  // Loop until we're reconnected
  while (!client.connected()) {
    Serial.print("********** Attempting MQTT connection...");
    // Attempt to connect
    if (client.connect("ESP32Client",username, "")) {
      Serial.println("-> MQTT client connected");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println("-> try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}


Previous : ESP8266 MQTT